mirror of
https://chromium.googlesource.com/chromium/tools/depot_tools.git
synced 2026-01-11 18:51:29 +00:00
0e6d5ed1bb
This changes autoninja.bat so that it refers explicitly to the depot_tools version of Python rather than depending on what is in the path. This helps to make autoninja behave more consistently and makes it easier for us to remove python.bat from the path. Bug: 777069 Change-Id: I6d878f58e2f8be70d06a182d059caa9fbedaedbd Reviewed-on: https://chromium-review.googlesource.com/c/chromium/tools/depot_tools/+/2753458 Reviewed-by: Dirk Pranke <dpranke@google.com> Commit-Queue: Bruce Dawson <brucedawson@chromium.org>
55 lines
2.1 KiB
Batchfile
Executable File
55 lines
2.1 KiB
Batchfile
Executable File
@echo off
|
|
:: Copyright 2017 The Chromium Authors. All rights reserved.
|
|
:: Use of this source code is governed by a BSD-style license that can be
|
|
:: found in the LICENSE file.
|
|
|
|
setlocal
|
|
|
|
set scriptdir=%~dp0
|
|
|
|
REM Set unique build ID.
|
|
FOR /f "usebackq tokens=*" %%a in (`%scriptdir%python-bin\python3.bat -c "import uuid; print(uuid.uuid4())"`) do set AUTONINJA_BUILD_ID=%%a
|
|
|
|
REM If a build performance summary has been requested then also set NINJA_STATUS
|
|
REM to trigger more verbose status updates. In particular this makes it possible
|
|
REM to see how quickly process creation is happening - often a critical clue on
|
|
REM Windows. The trailing space is intentional.
|
|
if "%NINJA_SUMMARIZE_BUILD%" == "1" set NINJA_STATUS=[%%r processes, %%f/%%t @ %%o/s : %%es ]
|
|
|
|
:loop
|
|
IF NOT "%1"=="" (
|
|
@rem Tell goma or reclient to not do network compiles.
|
|
IF "%1"=="--offline" (
|
|
SET GOMA_DISABLED=1
|
|
SET RBE_remote_disabled=1
|
|
)
|
|
IF "%1"=="-o" (
|
|
SET GOMA_DISABLED=1
|
|
SET RBE_remote_disabled=1
|
|
)
|
|
SHIFT
|
|
GOTO :loop
|
|
)
|
|
|
|
REM Execute whatever is printed by autoninja.py.
|
|
REM Also print it to reassure that the right settings are being used.
|
|
REM Don't use vpython - it is too slow to start.
|
|
REM Don't use python3 because it doesn't work in git bash on Windows and we
|
|
REM should be consistent between autoninja.bat and the autoninja script used by
|
|
REM git bash.
|
|
FOR /f "usebackq tokens=*" %%a in (`%scriptdir%python-bin\python3.bat %scriptdir%autoninja.py "%*"`) do echo %%a & %%a
|
|
@if errorlevel 1 goto buildfailure
|
|
|
|
REM Use call to invoke python script here, because we use python via python3.bat.
|
|
@if "%NINJA_SUMMARIZE_BUILD%" == "1" call %scriptdir%python-bin\python3.bat %scriptdir%post_build_ninja_summary.py %*
|
|
@call %scriptdir%python-bin\python3.bat %scriptdir%ninjalog_uploader_wrapper.py --cmdline %*
|
|
|
|
exit /b
|
|
:buildfailure
|
|
|
|
@call %scriptdir%python-bin\python3.bat %scriptdir%ninjalog_uploader_wrapper.py --cmdline %*
|
|
|
|
REM Return an error code of 1 so that if a developer types:
|
|
REM "autoninja chrome && chrome" then chrome won't run if the build fails.
|
|
cmd /c exit 1
|