mirror of
https://chromium.googlesource.com/chromium/tools/depot_tools.git
synced 2026-01-11 18:51:29 +00:00
a358defc3f
This reverts commit ba352e00ba.
Reason for revert: Unfortunately this breaks this command when run
from a normal cmd.exe prompt:
autoninja ..\..\base\win\access_token.cc^^
The escaping of ^^ as it passes through batch files is very finicky, but important.
Original change's description:
> Update autoninja.bat to work with other shells.
>
> Other shells, such as TCC, have subtle differences in how batch files are processed. This will not break cmd.exe compatibility.
>
> Without the "call" command, running a nested batch file should, according to CMD.exe "rules", cancel the current batch file and run the new one. However, the 'FOR /f "usebackq"' command will call the batch file and return. One could argue for both approaches, however, adding the "call" command doesn't seem to affect cmd.exe and fixes the other shell.
>
> There is a similar issue with the "do" (in the FOR command) block and the use of the '&' separator. The '%a' variable isn't expanded, but adding the '()' block works in both instances.
>
> Bug: 1351817
> Change-Id: Idd685a64404ea950b71e1f3cc0f5d1e3bf13b8b6
> Reviewed-on: https://chromium-review.googlesource.com/c/chromium/tools/depot_tools/+/3824199
> Commit-Queue: Allen Bauer <kylixrd@chromium.org>
> Reviewed-by: Bruce Dawson <brucedawson@chromium.org>
Bug: 1351817
Change-Id: I9d204a3369c468664c0cff247ed1a53065dfebfd
Reviewed-on: https://chromium-review.googlesource.com/c/chromium/tools/depot_tools/+/3829729
Bot-Commit: Rubber Stamper <rubber-stamper@appspot.gserviceaccount.com>
Commit-Queue: Bruce Dawson <brucedawson@chromium.org>
57 lines
2.1 KiB
Batchfile
Executable File
57 lines
2.1 KiB
Batchfile
Executable File
@echo off
|
|
:: Copyright 2017 The Chromium Authors. All rights reserved.
|
|
:: Use of this source code is governed by a BSD-style license that can be
|
|
:: found in the LICENSE file.
|
|
|
|
setlocal
|
|
|
|
set scriptdir=%~dp0
|
|
|
|
if not defined AUTONINJA_BUILD_ID (
|
|
:: Set unique build ID.
|
|
FOR /f "usebackq tokens=*" %%a in (`%scriptdir%python-bin\python3.bat -c "import uuid; print(uuid.uuid4())"`) do set AUTONINJA_BUILD_ID=%%a
|
|
)
|
|
|
|
:: If a build performance summary has been requested then also set NINJA_STATUS
|
|
:: to trigger more verbose status updates. In particular this makes it possible
|
|
:: to see how quickly process creation is happening - often a critical clue on
|
|
:: Windows. The trailing space is intentional.
|
|
if "%NINJA_SUMMARIZE_BUILD%" == "1" set NINJA_STATUS=[%%r processes, %%f/%%t @ %%o/s : %%es ]
|
|
|
|
:loop
|
|
IF NOT "%1"=="" (
|
|
:: Tell goma or reclient to not do network compiles.
|
|
IF "%1"=="--offline" (
|
|
SET GOMA_DISABLED=1
|
|
SET RBE_remote_disabled=1
|
|
)
|
|
IF "%1"=="-o" (
|
|
SET GOMA_DISABLED=1
|
|
SET RBE_remote_disabled=1
|
|
)
|
|
SHIFT
|
|
GOTO :loop
|
|
)
|
|
|
|
:: Execute whatever is printed by autoninja.py.
|
|
:: Also print it to reassure that the right settings are being used.
|
|
:: Don't use vpython - it is too slow to start.
|
|
:: Don't use python3 because it doesn't work in git bash on Windows and we
|
|
:: should be consistent between autoninja.bat and the autoninja script used by
|
|
:: git bash.
|
|
FOR /f "usebackq tokens=*" %%a in (`%scriptdir%python-bin\python3.bat %scriptdir%autoninja.py "%*"`) do echo %%a & %%a
|
|
@if errorlevel 1 goto buildfailure
|
|
|
|
:: Use call to invoke python script here, because we use python via python3.bat.
|
|
@if "%NINJA_SUMMARIZE_BUILD%" == "1" call %scriptdir%python-bin\python3.bat %scriptdir%post_build_ninja_summary.py %*
|
|
@call %scriptdir%python-bin\python3.bat %scriptdir%ninjalog_uploader_wrapper.py --cmdline %*
|
|
|
|
exit /b %ERRORLEVEL%
|
|
:buildfailure
|
|
|
|
@call %scriptdir%python-bin\python3.bat %scriptdir%ninjalog_uploader_wrapper.py --cmdline %*
|
|
|
|
:: Return an error code of 1 so that if a developer types:
|
|
:: "autoninja chrome && chrome" then chrome won't run if the build fails.
|
|
cmd /c exit 1
|