mirror of
https://chromium.googlesource.com/chromium/tools/depot_tools.git
synced 2026-01-11 10:41:31 +00:00
655afebfcd
It is sometimes helpful to do a full build of Chrome using goma while online and then do incremental builds without goma while offline or with poor network bandwidth. Turning off goma in gn args triggers a full rebuild but the GOMA_DISABLED environment variable can be used to disable goma without triggering a rebuild. In order to make this feature easier to discover and use this change adds support for -o/--offline to autoninja. autoninja -h will mention this flag and autoninja.bat/autoninja.py handle it appropriately. This means setting the environment variable in autoninja.bat, and using it to adjust the -j value and stripping it out in autoninja.py. The bash script that wraps autoninja.py on Linux and OSX did not need updating because the Python script can emit 'GOMA_DISABLED=1 ninja ...' and this is executed by bash. This was produced during pair programming with jessemckenna@ Bug: b/172039612 Change-Id: Ifcfbc598ac20f23e5fe013e02979b5b8c2851b01 Reviewed-on: https://chromium-review.googlesource.com/c/chromium/tools/depot_tools/+/2510818 Auto-Submit: Bruce Dawson <brucedawson@chromium.org> Commit-Queue: Dirk Pranke <dpranke@google.com> Reviewed-by: Dirk Pranke <dpranke@google.com>
45 lines
1.7 KiB
Batchfile
Executable File
45 lines
1.7 KiB
Batchfile
Executable File
@echo off
|
|
:: Copyright 2017 The Chromium Authors. All rights reserved.
|
|
:: Use of this source code is governed by a BSD-style license that can be
|
|
:: found in the LICENSE file.
|
|
|
|
setlocal
|
|
|
|
REM Set unique build ID.
|
|
FOR /f "usebackq tokens=*" %%a in (`python -c "from __future__ import print_function; import uuid; print(uuid.uuid4())"`) do set AUTONINJA_BUILD_ID=%%a
|
|
|
|
REM If a build performance summary has been requested then also set NINJA_STATUS
|
|
REM to trigger more verbose status updates. In particular this makes it possible
|
|
REM to see how quickly process creation is happening - often a critical clue on
|
|
REM Windows. The trailing space is intentional.
|
|
if "%NINJA_SUMMARIZE_BUILD%" == "1" set NINJA_STATUS=[%%r processes, %%f/%%t @ %%o/s : %%es ]
|
|
|
|
set scriptdir=%~dp0
|
|
|
|
:loop
|
|
IF NOT "%1"=="" (
|
|
@rem Tell goma to not do network compiles.
|
|
IF "%1"=="--offline" SET GOMA_DISABLED=1
|
|
IF "%1"=="-o" SET GOMA_DISABLED=1
|
|
SHIFT
|
|
GOTO :loop
|
|
)
|
|
|
|
REM Execute whatever is printed by autoninja.py.
|
|
REM Also print it to reassure that the right settings are being used.
|
|
FOR /f "usebackq tokens=*" %%a in (`vpython %scriptdir%autoninja.py "%*"`) do echo %%a & %%a
|
|
@if errorlevel 1 goto buildfailure
|
|
|
|
REM Use call to invoke vpython script here, because we use vpython via vpython.bat.
|
|
@if "%NINJA_SUMMARIZE_BUILD%" == "1" call vpython.bat %scriptdir%post_build_ninja_summary.py %*
|
|
@call vpython.bat %scriptdir%ninjalog_uploader_wrapper.py --cmdline %*
|
|
|
|
exit /b
|
|
:buildfailure
|
|
|
|
@call vpython.bat %scriptdir%ninjalog_uploader_wrapper.py --cmdline %*
|
|
|
|
REM Return an error code of 1 so that if a developer types:
|
|
REM "autoninja chrome && chrome" then chrome won't run if the build fails.
|
|
cmd /c exit 1
|