mirror of
https://chromium.googlesource.com/chromium/tools/depot_tools.git
synced 2026-01-11 02:31:29 +00:00
544594e0b2
This reverts commit6754c49e02. Reason for revert: will be relanded with fixed batch comments that triggered parser error. Original change's description: > Revert "Make depot_tools scripts return exit codes properly on all platforms." > > This reverts commit7c4f7ec408. > > Reason for revert: bugs reported by users (see comments in Gerrit). > error: block. was unexpected at this time. > > Original change's description: > > Make depot_tools scripts return exit codes properly on all platforms. > > > > Changes: > > 1. Windows: exit /b %errorlevel% should be used instead of goto :EOF to get valid exit codes during cmd /c <script>.bat invocation. > > 2. Windows: delayed var expansion is required in update_depot_tools.bat exit code generation. > > 3. Posix: update_depot_tools returns exit code from update_git_repo function in case of a failure. > > > > A rule of thumb on Windows: goto :EOF should not be used if %errorlevel% must be returned for all possible invocations. > > > > Test case for update_depot_tools changes: > > 1. Make a change to depot_tools sources that will conflict with next depot_tools update > > 2. Run update_depot_tools either directly or via gclient > > 3. Expect a git error is triggered > > 4. Inspect %errorlevel% or $? depending on platform > > 5. Expected 1, but the actual result is 0. > > > > Test case for changes in other .bat files: > > 1. Make a change to depot_tools sources that will conflict with next depot_tools update > > 2. Run cmd /c gclient > > 3. Expect a git error is triggered > > 4. Inspect %errorlevel% > > 5. Expected 1, but the actual result is 0. > > > > Change-Id: I64459982bcd9cc3db1319a9b39224b7a7af8c5aa > > Reviewed-on: https://chromium-review.googlesource.com/c/chromium/tools/depot_tools/+/3688632 > > Reviewed-by: Josip Sokcevic <sokcevic@google.com> > > Commit-Queue: Josip Sokcevic <sokcevic@google.com> > > Auto-Submit: Aleksey Khoroshilov <akhoroshilov@brave.com> > > Reviewed-by: Bruce Dawson <brucedawson@chromium.org> > > Change-Id: I85d598af01d75588cdee77165d6af22270ee031d > No-Presubmit: true > No-Tree-Checks: true > No-Try: true > Reviewed-on: https://chromium-review.googlesource.com/c/chromium/tools/depot_tools/+/3694139 > Auto-Submit: Josip Sokcevic <sokcevic@google.com> > Commit-Queue: Rubber Stamper <rubber-stamper@appspot.gserviceaccount.com> > Bot-Commit: Rubber Stamper <rubber-stamper@appspot.gserviceaccount.com> Change-Id: I377f966ea1b1a567de815caca703b5e124a76b64 Reviewed-on: https://chromium-review.googlesource.com/c/chromium/tools/depot_tools/+/3696396 Reviewed-by: Josip Sokcevic <sokcevic@google.com> Reviewed-by: Bruce Dawson <brucedawson@chromium.org> Commit-Queue: Josip Sokcevic <sokcevic@google.com> Auto-Submit: Aleksey Khoroshilov <akhoroshilov@brave.com>
79 lines
2.7 KiB
Batchfile
79 lines
2.7 KiB
Batchfile
@echo off
|
|
:: Copyright (c) 2012 The Chromium Authors. All rights reserved.
|
|
:: Use of this source code is governed by a BSD-style license that can be
|
|
:: found in the LICENSE file.
|
|
|
|
:: This batch file will try to sync the root directory.
|
|
|
|
setlocal enabledelayedexpansion
|
|
|
|
:: Windows freaks out if a file is overwritten while it's being executed. Copy
|
|
:: this script off to a temporary location and reinvoke from there before
|
|
:: running any git commands.
|
|
:: !ERRORLEVEL! syntax is used to get delayed expansion, because %ERRORLEVEL%
|
|
:: would return a value that was set prior entering the IF block.
|
|
IF "%~nx0"=="update_depot_tools.bat" (
|
|
COPY /Y "%~dp0update_depot_tools.bat" "%TEMP%\update_depot_tools_tmp.bat" >nul
|
|
if errorlevel 1 (
|
|
echo Error updating depot_tools, can't copy update_depot_tools.bat to TEMP.
|
|
exit /b !ERRORLEVEL!
|
|
)
|
|
:: Use call/exit to avoid leaving an orphaned window title.
|
|
call "%TEMP%\update_depot_tools_tmp.bat" "%~dp0" %*
|
|
exit /b !ERRORLEVEL!
|
|
)
|
|
|
|
setlocal disabledelayedexpansion
|
|
|
|
set DEPOT_TOOLS_DIR=%~1
|
|
SHIFT
|
|
|
|
:: Shall skip automatic update?
|
|
IF EXIST "%DEPOT_TOOLS_DIR%.disable_auto_update" GOTO :EOF
|
|
IF "%DEPOT_TOOLS_UPDATE%" == "0" GOTO :EOF
|
|
|
|
echo Updating depot_tools...
|
|
set GIT_URL=https://chromium.googlesource.com/chromium/tools/depot_tools.git
|
|
|
|
:: Download git for the first time if it's not present.
|
|
call git --version > nul 2>&1
|
|
if %ERRORLEVEL% == 0 goto :GIT_UPDATE
|
|
call "%DEPOT_TOOLS_DIR%bootstrap\win_tools.bat"
|
|
if errorlevel 1 (
|
|
echo Error updating depot_tools, no revision tool found.
|
|
exit /b %ERRORLEVEL%
|
|
)
|
|
|
|
:GIT_UPDATE
|
|
:: Now clear errorlevel so it can be set by other programs later.
|
|
set errorlevel=
|
|
|
|
cd /d "%DEPOT_TOOLS_DIR%."
|
|
call git config remote.origin.fetch > NUL
|
|
for /F %%x in ('git config --get remote.origin.url') DO (
|
|
IF not "%%x" == "%GIT_URL%" (
|
|
echo Your depot_tools checkout is configured to fetch from an obsolete URL
|
|
choice /N /T 60 /D N /M "Would you like to update it? [y/N]: "
|
|
IF not errorlevel 2 (
|
|
call git config remote.origin.url "%GIT_URL%"
|
|
)
|
|
)
|
|
)
|
|
:: depot_tools.zip archives generated before 2021-03-12 have instruction to
|
|
:: fetch only from old default git branch. Such branch won't be available
|
|
:: evenutally, so fetch config needs to be updated.
|
|
call git config --unset-all remote.origin.fetch
|
|
call git config --add remote.origin.fetch +refs/heads/*:refs/remotes/origin/*
|
|
call git fetch -q origin > NUL
|
|
call git checkout -q origin/main > NUL
|
|
if errorlevel 1 (
|
|
echo Failed to update depot_tools.
|
|
exit /b %ERRORLEVEL%
|
|
)
|
|
|
|
:: Sync CIPD and CIPD client tools.
|
|
call "%~dp0\cipd_bin_setup.bat"
|
|
|
|
:: Update git and python
|
|
call "%DEPOT_TOOLS_DIR%bootstrap\win_tools.bat"
|